//Pizza
ACTOR StupidRatPizzaWeapon : Weapon
{
	Inventory.RestrictedTo "StupidRatClass"
	Weapon.SelectionOrder 3700
	Obituary "%k got jelly'd"
	Inventory.Pickupmessage "$PICKUP_PISTOL_DROPPED"
	Weapon.AmmoUse 1
	Weapon.Ammotype "StupidRatPizzaAmmo" 
	+WEAPON.AMMO_OPTIONAL
	+weapon.noalert
	Tag "Pizza"
	States
	{
	Reload:
		TNT1 A 0 bright ACS_NamedExecuteAlways("RatDanceState")
		TNT1 A 0 A_GiveInventory("StupidRatDancing")
		TNT1 A 0 SetPlayerProperty(0,1,PROP_FROZEN)
		TNT1 A 0 A_PlaySound("characters/stupidrat/music",7,1,1,5)
		TNT1 A 0 ACS_NamedExecuteWithResult("SetRatChasecam2",40)
		TNT1 A 0 ACS_NamedExecuteWithResult("SpookyDoiseTime")
	Dance:
		TNT1 A 0 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
		SRWI D 10 bright 
		TNT1 A 0 A_jumpifinventory("reloadholding",1,"Dance")
		TNT1 A 0 SetPlayerProperty(0,0,PROP_FROZEN)
		TNT1 A 0 A_takeinventory("StupidRatDancing")
		TNT1 A 0 A_StopSound(7)
		TNT1 A 0 ACS_NamedExecuteWithResult("SetRatChasecam2",0)
		TNT1 A 0 ACS_NamedExecuteWithResult("SpookyDoiseTimeStop")
		TNT1 A 0 bright ACS_NamedExecuteAlways("RatCheeseState")
		SRWI DEFG 4 bright
		Goto Ready
	Ready: 
		TNT1 A 0 A_GiveInventory("StupidRatHoldingPizza")
		SRWI DEFG 4 bright A_WeaponReady(WRF_NOBOB|WRF_ALLOWRELOAD)
		Loop
	Deselect:
		TNT1 A 0 ACS_NamedExecuteWithResult("SetRatChasecam2",0)
		TNT1 A 0 A_StopSound(7)
	DeselectLoop:
		TNT1 A 0 A_TakeInventory("StupidRatHoldingPizza")
		TNT1 A 0 bright ACS_NamedExecuteAlways("StupidRatViewHeightReset")
		TNT1 A 0 SetPlayerProperty(0,0,PROP_FROZEN)
		TNT1 A 0 A_StopSound(6)
		SRWI A 0 A_Lower
		Loop
	Select:
		TNT1 A 0 bright ACS_NamedExecuteAlways("RatPizzaState")
		SelectLoop:
		SRWI A 0 A_Raise
		Loop
	Fire:
		SRWI D 4 bright A_JumpIfInventory("StupidRatPizzaAmmo",1,"ContinueFire")
		SRWI D 1 bright A_WeaponReady(WRF_NOBOB|WRF_NOFIRE)
		Goto Ready
	ContinueFire:
		TNT1 A 0 bright ACS_NamedExecuteAlways("RatPizzaAttack1State")
		SRWI H 4 Bright
		TNT1 A 0 SetPlayerProperty(0,1,PROP_FROZEN)
		//Start Bites
	BiteLoopCheck:
		SRWI D 0 bright A_JumpIfInventory("StupidRatPizzaBiteCount",0,"EndMunch") //Munch no more if you do all your munches
		SRWI H 0 bright A_JumpIfInventory("StupidRatPizzaAmmo",1,"ContinueMunch") //If you still have pizza to eat, do
	ContinueMunch:
		TNT1 A 0 a_alertmonsters
		TNT1 A 0 A_Playsound("characters/stupidrat/pizzaeat",1)
		TNT1 A 0 bright ACS_NamedExecuteAlways("RatPizzaAttack1State")
		SRWI I 4 bright A_jumpIfInventory("StupidRatPizzaAmmo",4,"FullMunch") //Full 4 hp munch
		SRWI H 4 bright A_takeinventory("StupidRatPizzaAmmo",0)
		TNT1 A 0 ACS_NamedExecuteWithResult("GiveHealthWithItem",ACS_NamedExecuteWithResult("CountStupidRatPizzaAmmo"),1)
		Goto EndMunch
	FullMunch:
		TNT1 A 0 a_alertmonsters
		TNT1 A 0 bright ACS_NamedExecuteAlways("RatPizzaAttack1State")
		TNT1 A 0 A_Playsound("characters/stupidrat/pizzaeat",1)
	// 	SRWI I 4 bright A_GiveInventory("Health", 4)
		SRWI I 4 bright ACS_NamedExecuteWithResult("GiveHealthWithItem",4,1)
		TNT1 A 0 A_SpawnItemEx("StupidRatFoodParticle",10,0,24,5,0,6,random(-45,45))
		SRWI H 4 bright A_takeinventory("StupidRatPizzaAmmo",8)
		SRWI I 0 bright A_GiveInventory("StupidRatPizzaBiteCount",1)
		Goto BiteLoopCheck
	EndMunch:
		TNT1 A 0 a_alertmonsters
		TNT1 A 0 bright ACS_NamedExecuteAlways("RatPizzaAttack2State")
		SRWI I 15 bright
		TNT1 A 0 SetPlayerProperty(0,0,PROP_FROZEN)
		SRWI I 0 bright A_TakeInventory("StupidRatPizzaBiteCount",0)
		Goto Ready
	}
}